diff --git a/app-admin/webapp-config/metadata.xml b/app-admin/webapp-config/metadata.xml
new file mode 100644
index 0000000..4c0ca42
--- /dev/null
+++ b/app-admin/webapp-config/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ceamac@gentoo.org</email>
+		<name>Viorel Munteanu</name>
+	</maintainer>
+	<use>
+		<flag name="portage">Propagate python_targets dependencies to <pkg>sys-apps/portage</pkg></flag>
+	</use>
+</pkgmetadata>
diff --git a/app-admin/webapp-config/webapp-config-2.ebuild b/app-admin/webapp-config/webapp-config-2.ebuild
new file mode 100644
index 0000000..adf111d
--- /dev/null
+++ b/app-admin/webapp-config/webapp-config-2.ebuild
@@ -0,0 +1,32 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Gentoo config file for missing webapp-config"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+S="${WORKDIR}"
+
+LICENSE="GPL-2+"
+SLOT="ceamac"
+KEYWORDS="~amd64"
+
+RESTRICT="bindist"
+
+BDEPEND="app-admin/webapp-config:0"
+
+pkg_setup() {
+	[[ ${ROOT} != ${BROOT} ]] && export MAKELINKS=1
+}
+
+src_install() {
+	if [[ -n ${MAKELINKS} ]]; then
+		dodir /etc/vhosts
+		dodir /usr/sbin
+		keepdir /var/www/
+
+		# Ugly, but intentional.  This is supposed to point outside of ${ROOT}.
+		dosym "${BROOT}"/etc/vhosts/webapp-config /etc/vhosts/webapp-config
+		dosym "${BROOT}"/usr/sbin/webapp-config /usr/sbin/webapp-config
+	fi
+}
diff --git a/app-admin/webapp-config/webapp-config-9999.ebuild b/app-admin/webapp-config/webapp-config-9999.ebuild
new file mode 100644
index 0000000..09335c2
--- /dev/null
+++ b/app-admin/webapp-config/webapp-config-9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 prefix
+
+if [[ ${PV} = 9999* ]]
+then
+	EGIT_REPO_URI="/home/viorel/src/webapp-config/"
+	EGIT_BRANCH="fixes"
+	inherit git-r3
+else
+	SRC_URI="https://dev.gentoo.org/~ceamac/${CATEGORY}/${PN}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Gentoo's installer for web-based applications"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Webapp-config"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+portage"
+
+DEPEND="app-text/xmlto
+	sys-apps/gentoo-functions"
+RDEPEND="
+	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	eprefixify WebappConfig/eprefix.py config/webapp-config
+}
+
+python_compile_all() {
+	emake -C doc/
+}
+
+python_test() {
+	PYTHONPATH="." "${EPYTHON}" WebappConfig/tests/external.py -v ||
+		die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# distutils-r1 installs the scripts in /usr/bin in PEP517 mode
+	mv "${ED}"/usr/bin "${ED}"/usr/sbin || die "Cannot rename scripts directory to /usr/sbin"
+
+	insinto /etc/vhosts
+	doins config/webapp-config
+
+	keepdir /usr/share/webapps
+	keepdir /var/db/webapps
+
+	dodoc AUTHORS
+	doman doc/*.[58]
+}
+
+pkg_postinst() {
+	elog "Now that you have upgraded webapp-config, you **must** update your"
+	elog "config files in /etc/vhosts/webapp-config before you emerge any"
+	elog "packages that use webapp-config."
+}